Étude de la décroissance radioactive : approche statistique




Comment mettre en évidence la loi de décroissance radioactive ?

(Modélisation à l'aide de la calculatrice)

On cherche à mettre en évidence l’évolution temporelle de la population de noyaux radioactifs au sein d’un échantillon.
L’utilisation de sources radioactives étant interdite dans un cadre scolaire, il convient de trouver un autre moyen d’étude.
Or il se trouve que les lois physiques qui régissent cette évolution sont de natures statistiques,  identiques à celles d’une population de dés.
C’est donc cette similitude que nous allons utiliser.

1. “L’idée du TP”

Très largement inspiré d'une activité du livre de TS Tomasino chez Nathan.

Vous disposez d’un nombre suffisant de dés.
Ces dés sont “radioactifs” c'est-à-dire qu’ils peuvent potentiellement se désintégrer
(peu importe le type de radioactivité).
Afin que ces dés puissent manifester leur “radioactivité”, ils doivent être lancés tous ensembles.
Un dé est considéré comme désintégré s’il donne le chiffre 1.
La population restante de dés radioactifs est l’ensemble des dés qui n’ont pas donné 1.
Ces dés restants sont à nouveau lancés, on enlève ceux qui ont donné 1 et ainsi de suite...
L’expérience se termine à partir du moment où vous n’aurez plus de dés dans les mains.

2. Travail à effectuer

Comme il a déjà été précisé, le phénomène de désintégration radioactive possède un caractère probabiliste.
Si l’on ne peut prévoir exactement le devenir d’une source à un instant donné, on peut cependant estimer ce devenir avec une assez bonne précision.
Pour ce faire il convient ici de répéter plusieurs fois l’opération décrite plus haut de façon à moyenner les résultats.
Exemple :
Lancer n°0 : 10 dés en mains. On les lance
Lancer n°1 : 2 dés ont donné 1, ceux-ci ne sont alors plus radioactifs puisqu’ils ont manifesté leur radioactivité.
Le nombre de dés radioactifs restants est donc 8.
Lancer n°2 : on lance les 8 dés restants. 1 dé donne 1. Il reste donc 7 dés radioactifs.
Etc, etc…

Chaque groupe répète ainsi la méthode exposée plus haut. Les résultats de chaque groupe d'élèves sont mis en commun et la moyenne du nombre de dés restants pour chaque lancer est calculée.

Numéro du lancer

Nombre de dés restants pour chaque groupe Moyenne du Nombre de dés restants
1                  
2                  
3                  
4                  
...                  

En utilisant le mode Tableur / Statistiques de la calculatrice.
Rentrer les valeurs précédentes.

Afficher la courbe N = f ( Numéro du Lancer ).

Modéliser cette courbe et relever les valeurs de la modélisation.

On peut utiliser le générateur de fonction aléatoire de la calculatrice pour faire le même travail (on peut ainsi modifier les caractéristiques des dés et leur nombre).

Ce programme est non réalisable sur Graph 25

Décroissance radioactive

'Remise à zéro des listes et des variables'
ClrList1
ClrList2
S-Gph1 DrawOff
S-Gph3 DrawOff
0→A~Z
'Définition du dé'
"Nombre de faces"?→N
"Nombre de des"?→I
1→J
'Les valeurs d'origine sont placées dans la première ligne des listes 1 et 2'
J→List 1[J]
I→List 2[J]
'Boucle de lancer des dés'
LblT
0→X
'Nombre de dés restants à lancer'
For 1→T To I
'Tirage aléatoire'
Int(Ran#*N+1)→V
'Test de la valeur du dé (valeur 1 est la valeur de référence)'
If V=1
Then X+1→X
IfEnd
Next
'Valeurs du numéro de tirage et du nombre de dés restants'
J+1→J
I-X→I
J→List 1[J]
I→List 2[J]
ClrGrpah
'Chaque couple de valeurs est représentée sur un graphique
Remarque : l'échelle est automatique dans ce cas'

S-Gph1 DrawOn,Scatter,List 1,List 2,1,cross
DrawStat
'Boucle d'attente : la touche Getkey 31 correspond à la touche EXE'
Do
LpWhile Getkey≠31
"Tirage suivant : touche EXE"
'Boucle d'attente avant le lancer des dés restants'
Do
LpWhile Getkey≠31
'On lance des dés tant qu'il reste des dés !'
If I=1
Then Goto T
IfEnd
'On représente la courbe de modélisation (Log)'
S-Gph3 DrawOn,Log,List 1,List 2,1
DrawStat
'Boucle d'attente avant d'afficher les résultats numériques de la modélisation'
Do
LpWhile Getkey≠31
LogReg List 1,List 2,1



On peut aussi imaginer une variante qui crée les listes. Le traitement statistique sera alors réalisé en mode statistique (cette fois, c'est possible avec la Graph 25 !)

Variante du programme

'Remise à zéro des listes et des variables'
ClrList 1
ClrList 2
0→A~Z
'Définition du dé'
"Nombre de faces"?→N
"Nombre de des"?→I
1→J
'Les valeurs d'origine sont placées dans la première ligne des listes 1 et 2'
J→List1[J]
I→List2[J]
'Boucle de lancer des dés'
LblT
0→X
'Nombre de dés restants à lancer'
For 1→T To I
'Tirage aléatoire'
Int(Ran#*N+1)→V
'Test de la valeur du dé (valeur 1 est la valeur de référence)'
If V=1
Then X+1→X
IfEnd
Next
'Valeurs du numéro de tirage et du nombre de dés restants'
J+1→J
I-X→I
J→List1[J]
I→List2[J]
If I>0
Then Goto T
IfEnd